Die Mathe-Redaktion - 25.11.2017 04:51 - Registrieren/Login
Auswahl
Schwarzes Brett
Aktion im Forum
Suche
Stichwortsuche in Artikeln und Links von Matheplanet
Suchen im Forum
Suchtipps

Bücher
Englische Bücher
Software
Suchbegriffe:
Mathematik bei amazon
Naturwissenschaft & Technik
In Partnerschaft mit Amazon.de
Kontakt
Mail an Matroid
[Keine Übungsaufgaben!]
Impressum

Bitte beachten Sie unsere Nutzungsbedingungen, die Distanzierung, unsere Datenschutzerklärung und
die Forumregeln.

Sie können Mitglied werden oder den Newsletter bestellen.

Der Newsletter Okt. 2017

Für Mitglieder
Mathematisch für Anfänger
Wer ist Online
Aktuell sind 343 Gäste und 3 Mitglieder online.

Sie können Mitglied werden:
Klick hier.

Über Matheplanet
 
Zeichnen einer Weltkugel mit einem Commodore Plus 4
Freigegeben von matroid am Do. 19. Oktober 2017 15:53:20
Verfasst von Delastelle -   367 x gelesen [Gliederung] [Statistik] Druckbare Version Druckerfreundliche Version
Spiele+Rätsel

Im Jahr 1985 gab es von Commodore den Computer Plus 4 mit 64 KByte Speicher. Weiterhin gab es die Broschüre "BASIC Einmaleins des Programmierens" mit einem Umfang von 72 Seiten zum Programmieren in der Programmiersprache BASIC von Dr.Ursula Grote und Prof.Horst Völz. In der Broschüre war das Programm "GLOBUS" abgedruckt. Dieses konnte auf einem DDR-Computer eine Weltkugel zeichnen. Ich habe dieses heute 32 Jahre alte Programm auf einem virtuellen Commodore Plus 4 (Emulator vice) laufen lassen.


Eingaben 30,30,23,45

Laden

In meinem Notizbuch (siehe meine Stäbchen im Profil "Delastelle") habe ich das Programm "GLOBUS.P00" hochgeladen.
Es muss im Verzeichnis vom Emulator "VICE" stehnen.
Den Emulator "VICE" kann man hier herunterladen:
vice-emu.sourceforge.net/index.html#download
Das Programm "GLOBUS" habe ich leicht an den Commodore Plus 4 angepasst.


Im Gegensatz zum Commodore C64 besaß der Commodore Plus 4 ca.64 KBytes Speicher für BASIC-Programme.

ein paar BASIC-Befehle

Ein paar nützliche Commodore-BASIC-Befehle:
DIRECTORY // zeigt Dateien im aktuellen Verzeichnis an
DLOAD"NAME" // lädt ein Programm von Festplatte
DSAVE"NAME" // speichert ein Programm auf Festplatte
GRAPHIC 0, GRAPHIC 1 // ausschalten, einschalten des Grafikbildschirms
LIST, LIST 100-200 // zeigt Zeilen eines BASIC-Programms an
PRINT, PRINT PI // Bildschirmausgabe
REM TEXT // Kommentar
RUN // Programmstart
SCNCLR // Bildschirm löschen
X = 1, PI = 3.14159265 // Zuweisung einer Variable
 

Umbelegung der Tastatur unter VICE

Beim Arbeiten mit dem VICE-Emulator sind die Tastatureingaben zum Teil mit andern Zeichen belegt.
(Deutscher Tastaturtreiber)

PC-Taste -> VICE-Zeichen
ö -> :
, -> -
ß -> +
ä -> ;
, -> ,
. -> .
# -> =
+ -> *
- -> /
; -> <
: -> >
Z -> Y
Y -> Z

ein paar Erläuterungen zum Listing

68 DRAW ,X1,201-Y1 TO X2,201-Y2: GOTO 130 // DRAW zeichnet Punkte und Linien
261 D2=3: INPUT"DIMENSION 2/3 ";D2 // normalerweise wird auf eine Kugel gezeichnet,
                                   // es gibt aber auch eine 2D-Ansicht der Punkte
265 RESTORE: GRAPHIC 1 // Rücksetzen des Zeigers für DATA-Einlesen und Grafikbildschirm anschalten
339 FOR J=1 TO 292: IF J>1 THEN RA=A: RB=B // RA und RB sind die alten Bildpunkte für die 2-D Ansicht
340 READ A,B: IF A=.1 THEN D0=B: A=A0: B=B0: C0=0 // wenn in A = .1 steht wird aktuelles n-Eck beendet (fertiges Objekt)
390 FOR L=0 TO PI-Q+0.1 STEP Q // Zeichnen der Längenkreise, +0.1 damit letzer Kreis auch gezeichnet wird
395 F1=0: CL=COS(L): SL=SIN(L) // F1 = 0 bedeutet, dass der Startpunkt nicht gezeichnet wird, später werden die Strecken gezeichnet

Handhabung

(1) VICE PLUS 4 starten (xplus4.exe)
(2) Options -> Double size // doppelte Bildschirmgröße
(3) File -> Autostart disk -> "Globus.P00"
(4) DLOAD"GLOBUS" // laden von Festplatte
(5) RUN // starten
(6) Eingabe 30,30,23,45,3,J // Globus Eingaben
(7) (Berechnung)
(8) Options -> Maximum Speed -> No limit // Beschleunigung der Berechnung um den Faktor 58x (bei mir)
(9) (Berechnung fertig) Options -> Maximum Speed -> 100 %
(10) (eintippen) H , H // Programmende erreicht, Abbruch Programm, Grafikbildschirm schaltet sich ab


Der Eingabebildschirm von "GLOBUS"

Abschluß

Die Rechenzeit für "GLOBUS.P00" unter VICE beträgt bei den
Eingaben 30/30/23/45/3/J etwa 368 Sekunden bis das Bild fertig gezeichnet ist.
Durch Verwendung der Beschleunigung (siehe oben Punkt 8) sinkt die Rechenzeit bei mir
auf ca. 12,4 Sekunden.

Ich hoffe ihr bekommmt das Programm auch zum Laufen und habt viel Spaß an der gezeichneten Weltkugel!

Viele Grüße
Ronald

Commodore Basic
5 PI=3.14159265
10 PRINT"GLOBUS":GOTO 210
15 REM KUGEL-POLAR
20 Y=R*CP: X=Y*CL: Y=Y*SL: Z=R*SP
30 XX=AX*X+AY*Y+AZ*Z: YY=BX*X+BY*Y+BZ*Z
40 ZZ=CX*X+CY*Y+CZ*Z: IF YY>0 THEN F2=0: F1=0: RETURN
50 X2=INT(X0+XX+H): Y2=INT(Y0-ZZ+H): F2=1
60 IF F1=0 THEN X1=X2: Y1=Y2: F1=1: RETURN
65 REM GERADE
67 IF D2=2 THEN DRAW ,RA/2+180,201-(RB+90) TO A/2+180,201-(B+90): GOTO 130
68 DRAW ,X1,201-Y1 TO X2,201-Y2: GOTO 130
130 F1=F2: X1=X2: Y1=Y2: RETURN
135 REM KREIS
140 Y2=0: D=INT(R/SQR(2)+H): X2=R*R: X=R: R2=X2+D
150 FOR Y=0 TO D: IF Y2+X2>R2 THEN X2=X2-X-X+1: X=X-1
160 DRAW ,X0+X,Y0+Y: DRAW ,X0+Y,Y0+X
170 DRAW ,X0-Y,Y0+X: DRAW ,X0-X,Y0+Y
180 DRAW ,X0-X,Y0-Y: DRAW ,X0-Y,Y0-X
190 DRAW ,X0+Y,Y0-X: DRAW ,X0+X,Y0-Y: Y2=Y2+Y+Y+1
200 NEXT Y: RETURN
205 REM MAIN
210 PRINT"H.VOELZ 1985": PRINT
220 PRINT"ALLE WINKEL IN GRAD": BM=PI/180
230 INPUT"GEOGRAFISCHE LAENGE ";CW: C=-(CW+90)*BM
240 INPUT"GEOGRAFISCHE BREITE ";AW: A=-AW*BM
250 INPUT"NEIGUNG DER ACHSE ";BW: B=-BW*BM
260 INPUT"ABSTAND DER KREISE ";QW: Q=QW*BM
261 D2=3: INPUT"DIMENSION 2/3 ";D2
262 INPUT"WEITER (J/N)";K$: IF K$="N" THEN STOP
265 RESTORE: GRAPHIC 1
270 SCNCLR: O=4: X0=160: Y0=100: R=100: H=.5
275 IF D2=3 THEN GOSUB 140
280 S1=SIN(A): S2=SIN(B): S3=SIN(C)
290 C1=COS(A): C2=COS(B): C3=COS(C)
300 AX=C2*C3: AY=-C2*S3: AZ=S2
310 BX=C1*S3+S1*S2*C3: BY=C1*C3-S1*S2*S3
320 BZ=-S1*C2: CX=S1*S3-C1*S2*C3
330 CY=S1*C3+C1*S2*S3: CZ=C1*C2: F1=0: C0=1
335 REM KARTE
339 FOR J=1 TO 292: IF J>1 THEN RA=A: RB=B
340 READ A,B: IF A=.1 THEN D0=B: A=A0: B=B0: C0=0
350 IF C0=1 THEN A0=A: B0=B: C0=-1
360 L=A*BM: P=-B*BM: CL=COS(L): SL=SIN(L): CP=COS(P): SP=SIN(P): GOSUB 20
370 IF C0=0 THEN A=D0: READ B: C0=1: F1=0: GOTO 350
380 NEXT J
382 IF D2=2 GOTO 450
385 REM LAENGENKREISE
390 FOR L=0 TO PI-Q+0.1 STEP Q
395 F1=0: CL=COS(L): SL=SIN(L)
400 FOR P=0 TO PI+PI+BM STEP(2.5*BM): CP=COS(P): SP=SIN(P): GOSUB 20
410 NEXT P: NEXT L
415 REM BREITENKREISE
420 FOR P=-PI/2+Q TO PI/2-Q+0.1 STEP Q
425 F1=0: CP=COS(P): SP=SIN(P)
430 FOR L=0 TO PI+PI+BM STEP(2.5*BM): CL=COS(L): SL=SIN(L): GOSUB 20
440 NEXT L: NEXT P
450 PRINT"LAENGE=";CW: PRINT"BREITE=";AW: PRINT"NEIGUNG=";BW
460 PRINT"RASTER=";QW
463 K$=""
465 INPUT"WEITER (J/N)";K$: IF K$="N" THEN STOP
467 IF K$<>"J" THEN STOP
480 SCNCLR: GOTO 220
485 REM DATEN
490 DATA 355,50,1,51,2,52,358,56,359,57,357,58,353,58,355,55,356,55,.1,28,72
500 DATA 15,68,9,63,5,62,6,58,8,58,10,59,12,56,11,56,11,57,9,56,9,54,6,53,3,51
510 DATA 356,48,358,45,358,43,352,43,352,36,355,35,358,36,4,44,6,44,9,45,16
520 DATA 39,16,38,13,38,15,37,18,39,17,40,18,41,19,40,13,44,14,45,19,42,20,40
530 DATA 23,36,25,38,24,40,26,41,27,36,37,36,36,32,21,33,21,32,11,33,12,34
540 DATA 357,33,355,34,342,20,342,11,351,5,10,5,8,0,13,-8,12,-18,18,-24,28
550 DATA -24,41,-15,40,-5,52,12,43,12,38,20,34,28,43,12,58,18,60,22,51,23,48
560 DATA 30,68,23,77,8,80,10,80,7,82,8,80,10,80,15,90,22,95,16,97,17,99,8
570 DATA 104,2,100,13,106,8,110,13,106,20,109,21,109,19,121,27,121,40
580 DATA 124,39,126,33,130,35,131,41,140,48,140,57,160,61,155,51
590 DATA 163,55,190,67,130,72,95,82,95,76,69,69,35,65,33,67,38,67
600 DATA 42,68,.1,12,54,13,55,15,54,21,55,23,59,30,60,22,61,26,66,24,66
610 DATA 16,55,.1,23,35,26,35,.1,32,35,34,35,.1,44,-25,47,-25,50,-12,44,-18
620 DATA .1,165,-47,172,-47,178,-38,172,-35,172,-40,.1,128,0,141,-9,153,-12
630 DATA 145,-5,.1,118,9,125,5,126,11,122,19,.1,90,8,107,-8,126,-10,106,-5
640 DATA .1,109,2,110,-3,117,-4,119,8,.1,118,-5,123,-5,125,2,120,2,.1,130,30
650 DATA 140,36,145,45,142,45,142,55,138,38,130,33,.1,49,38,55,37,51,45,54,48
660 DATA 48,47,.1,28,42,42,42,36,44,39,47,34,43,36,44,30,46,31,46,.1,350,51
670 DATA 353,53,354,55,353,56,350,53,.1,51,-67,102,-66,140,-67,172,-72
680 DATA 160,-81,210,-85,200,-76,225,-75,300,-63,298,-78,354,-71,.1
690 DATA 315,60,338,70,345,82,330,84,295,81,290,76,300,75,312,62,.1
700 DATA 346,63,346,68,336,67,337,63,.1,18,76,32,80,10,79,.1,50,72,55,71
710 DATA 69,78,.1,276,22,278,23,295,20,280,18,272,22,.1,288,13,283,9
720 DATA 279,9,276,11,276,15,272,17,273,22,270,21,269,19,263,20,263,28
730 DATA 277,30,279,24,278,31,307,48,296,60,282,63,280,51,265,60,280,70
740 DATA 286,68,282,63,296,62,298,66,280,74,300,83,228,70,200,70,193,67
750 DATA 195,62,202,57,190,53,215,60,235,48,236,35,250,22,245,32,255,18,273,12
760 DATA 279,8,283,8,278,-5,290,-19,283,-52,292,-55,296,-54,292,-51,294,-47
770 DATA 293,-45,315,-23,320,-23,322,-12,325,-6,310,0,308,5,298,11,.1
780 DATA 114,-22,132,-12,137,-12,140,-16,142,-11,152,-26,148,-43,135,-35
790 DATA 115,-35,.1,9,43,9,42,8,41,8,39,10,40,.1,-2,60,-2,62,.1,-7,63,-7,65
Edit: in Zeile 710 muss es statt 272,22 richtig 278,22 heißen. (vertippt)


Eingaben 270,30,23,45

Edit 2:
Ich habe jetzt das Programm noch an SCILAB angepasst.
Es ist nicht der kürzeste Code (enthält etwas Redundanz), aber er läuft.
SCILAB
// Laenge, Breite, Neigung der Achse, Abstand der Kreise
CW=45;AW=45;BW=23;QW=45;
ausgabe = 1;
feld = [355 50 1 51 2 52 358 56 359 57 357 58 353 58 355 55 356 55 0.1 28 72 ...
  15 68 9 63 5 62 6 58 8 58 10 59 12 56 11 56 11 57 9 56 9 54 6 53 3 51 ...
  356 48 358 45 358 43 352 43 352 36 355 35 358 36 4 44 6 44 9 45 16 ...
  39 16 38 13 38 15 37 18 39 17 40 18 41 19 40 13 44 14 45 19 42 20 40 ...
  23 36 25 38 24 40 26 41 27 36 37 36 36 32 21 33 21 32 11 33 12 34 ...
  357,33,355,34,342,20,342,11,351,5,10,5,8,0,13,-8,12,-18,18,-24,28 ...
  -24,41,-15,40,-5,52,12,43,12,38,20,34,28,43,12,58,18,60,22,51,23,48 ...
  30,68,23,77,8,80,10,80,7,82,8,80,10,80,15,90,22,95,16,97,17,99,8 ...
  104,2,100,13,106,8,110,13,106,20,109,21,109,19,121,27,121,40 ...
  124,39,126,33,130,35,131,41,140,48,140,57,160,61,155,51 ...
  163,55,190,67,130,72,95,82,95,76,69,69,35,65,33,67,38,67 ...
  42,68,.1,12,54,13,55,15,54,21,55,23,59,30,60,22,61,26,66,24,66 ...
  16,55,.1,23,35,26,35,.1,32,35,34,35,.1,44,-25,47,-25,50,-12,44,-18 ...
  .1 165 -47 172 -47 178 -38 172 -35 172 -40 .1 128 0 141 -9 153 -12 ...
  145 -5 .1 118 9 125 5 126 11 122 19 .1 90 8 107 -8 126 -10 106 -5 ...
  .1 109 2 110 -3 117 -4 119 8 .1 118 -5 123 -5 125 2 120 2 .1 130 30 ...
  140 36 145 45 142 45 142 55 138 38 130 33 .1 49 38 55 37 51 45 54 48 ...
  48 47 .1 28 42 42 42 36 44 39 47 34 43 36 44 30 46 31 46 .1 350 51 ...
  353 53 354 55 353 56 350 53 .1 51 -67 102 -66 140 -67 172 -72 ...
  160 -81 210 -85 200 -76 225 -75 300 -63 298 -78 354 -71 .1 ...
  315 60 338 70 345 82 330 84 295 81 290 76 300 75 312 62 .1 ...
  346 63 346 68 336 67 337 63 .1 18 76 32 80 10 79 .1 50 72 55 71 ...
  69 78 .1 276 22 278 23 295 20 280 18 278 22 .1 288 13 283 9 ...
  279 9 276 11 276 15 272 17 273 22 270 21 269 19 263 20 263 28 ...
  277 30 279 24 278 31 307 48 296 60 282 63 280 51 265 60 280 70 ...
  286 68 282 63 296 62 298 66 280 74 300 83 228 70 200 70 193 67 ...
  195 62 202 57 190 53 215 60 235 48 236 35 250 22 245 32 255 18 273 12 ...
  279 8 283 8 278 -5 290 -19 283 -52 292 -55 296 -54 292 -51 294 -47 ...
  293 -45 315 -23 320 -23 322 -12 325 -6 310 0 308 5 298 11 .1 ...
  114 -22 132 -12 137 -12 140 -16 142 -11 152 -26 148 -43 135 -35 ...
  115 -35 .1 9 43 9 42 8 41 8 39 10 40 .1 -2 60 -2 62 .1 -7 63 -7 65];
 
PI=3.14159265;
printf('GLOBUS\n');
printf('H.VOELZ 1985\n');
printf('ALLE WINKEL IN GRAD\n'); BM=PI/180;
printf('GEOGRAFISCHE LAENGE %f \n',CW); C=-(CW+90)*BM;
printf('GEOGRAFISCHE BREITE %f \n',AW); A=-AW*BM;
printf('NEIGUNG DER ACHSE %f \n',BW); B=-BW*BM;
printf('ABSTAND DER KREISE %f \n',QW); Q=QW*BM;
// RESTORE: GRAPHIC 1
// SCNCLR:
O=4; X0=160; Y0=100; R=100; H=.5
 
// REM KREIS
Y2=0; D=round(R/sqrt(2)+H); X2=R*R; X=R; R2=X2+D;
set(gca(),"auto_clear","off")
// set(gce(),'thickness',2);
 //for Y=0:D
 // if Y2+X2>R2 then X2=X2-X-X+1; X=X-1; end,
 // plot(X0+X,Y0+Y,'.'); plot(X0+Y,Y0+X,'.');
 // plot(X0-Y,Y0+X,'.'); plot(X0-X,Y0+Y,'.');
 // plot(X0-X,Y0-Y,'.'); plot(X0-Y,Y0-X,'.');
 // plot(X0+Y,Y0-X,'.'); plot(X0+X,Y0-Y,'.');
 // Y2=Y2+Y+Y+1;
 //end;
 // NEXT Y: RETURN
 
if (ausgabe == 1) then
 // (1) Kreis zeichnen
 kreis = 0:PI/180:2*PI;
 xkreis = R*cos(kreis)+X0;
 ykreis = R*sin(kreis)+Y0;
 for i = 1:360
  plot([xkreis(i),xkreis(i+1)],[ykreis(i),ykreis(i+1)]);
 end;
end;
 
S1=sin(A); S2=sin(B); S3=sin(C);
C1=cos(A); C2=cos(B); C3=cos(C);
AX=C2*C3; AY=-C2*S3; AZ=S2;
BX=C1*S3+S1*S2*C3; BY=C1*C3-S1*S2*S3;
BZ=-S1*C2; CX=S1*S3-C1*S2*C3;
CY=S1*C3+C1*S2*S3; CZ=C1*C2; F1=0; C0=1;
 
// (2) KARTE
stelle = 0;
F1=0; C0=1;
for J=1:292
// READ A,B:
stelle = stelle + 1; A = feld(stelle);
stelle = stelle + 1; B = feld(stelle);
if A==0.1 then D0=B; A=A0; B=B0; C0=0; end;
if C0==1 then A0=A; B0=B; C0=-1; end;
L=A*BM; P=-B*BM; CL=cos(L); SL=sin(L); CP=cos(P); SP=sin(P);
// GOSUB 20
 // REM KUGEL-POLAR
 Y=R*CP; X=Y*CL; Y=Y*SL; Z=R*SP
 XX=AX*X+AY*Y+AZ*Z; YY=BX*X+BY*Y+BZ*Z;
 ZZ=CX*X+CY*Y+CZ*Z;
 if YY>0 then F2=0; F1=0;
 else
  X2=round(X0+XX+H); Y2=round(Y0-ZZ+H); F2=1;
  if F1==0 then X1=X2; Y1=Y2; F1=1;
  else
   // REM GERADE
   plot([X1,X2],[Y1,Y2]);
   F1=F2; X1=X2; Y1=Y2;
  end;
 end;
 
if C0==0 then A=D0;
 stelle = stelle + 1;
 B = feld(stelle);
 // READ B:
 C0=1; F1=0;
 if C0==1 then A0=A; B0=B; C0=-1; end;
 L=A*BM; P=-B*BM; CL=cos(L); SL=sin(L); CP=cos(P); SP=sin(P);
 // GOSUB 20
 // REM KUGEL-POLAR
 Y=R*CP; X=Y*CL; Y=Y*SL; Z=R*SP
 XX=AX*X+AY*Y+AZ*Z; YY=BX*X+BY*Y+BZ*Z;
 ZZ=CX*X+CY*Y+CZ*Z;
 if YY>0 then F2=0; F1=0;
 else
  X2=round(X0+XX+H); Y2=round(Y0-ZZ+H); F2=1
  if F1==0 then X1=X2; Y1=Y2; F1=1;
  else
   // REM GERADE
   plot([X1,X2],[Y1,Y2]);
   F1=F2; X1=X2; Y1=Y2;
  end;
 end;
 
end;
// NEXT J
end;
 
if (ausgabe == 1) then
// (3) LAENGENKREISE
for L=0:Q:PI-Q+0.1
 F1=0; CL=cos(L); SL=sin(L);
 for P=0:2.5*BM:PI+PI+BM
  CP=cos(P); SP=sin(P);
  // GOSUB 20
 
  // REM KUGEL-POLAR
 Y=R*CP; X=Y*CL; Y=Y*SL; Z=R*SP
 XX=AX*X+AY*Y+AZ*Z; YY=BX*X+BY*Y+BZ*Z;
 ZZ=CX*X+CY*Y+CZ*Z;
 if YY>0 then F2=0; F1=0;
 else
  X2=round(X0+XX+H); Y2=round(Y0-ZZ+H); F2=1
  if F1==0 then X1=X2; Y1=Y2; F1=1;
  else
   // REM GERADE
   plot([X1,X2],[Y1,Y2]);
   F1=F2; X1=X2; Y1=Y2;
  end;
 end;
 
 end;
end;
// NEXT P: NEXT L
 
// (4) BREITENKREISE
for P=-PI/2+Q:Q:PI/2-Q+0.1
 F1=0; CP=cos(P); SP=sin(P);
 for L=0:2.5*BM:PI+PI+BM
  CL=cos(L); SL=sin(L);
// GOSUB 20
 
// REM KUGEL-POLAR
 Y=R*CP; X=Y*CL; Y=Y*SL; Z=R*SP
 XX=AX*X+AY*Y+AZ*Z; YY=BX*X+BY*Y+BZ*Z;
 ZZ=CX*X+CY*Y+CZ*Z;
 if YY>0 then F2=0; F1=0;
 else
  X2=round(X0+XX+H); Y2=round(Y0-ZZ+H); F2=1
  if F1==0 then X1=X2; Y1=Y2; F1=1;
  else
   // REM GERADE
   plot([X1,X2],[Y1,Y2]);
   F1=F2; X1=X2; Y1=Y2;
  end;
 end;
end;
end;
// NEXT L: NEXT P

Link auf diesen Artikel Link auf diesen Artikel  Druckbare Version Druckerfreundliche Version  Einen Freund auf diesen Artikel aufmerksam machen Weitersagen Kommentare zeigen Kommentare  
pdfFür diesen Artikel gibt es keine pdf-Datei


Arbeitsgruppe Alexandria Dieser Artikel ist nicht im Verzeichnis der Arbeitsgruppe Alexandria eingetragen.
[Die Arbeitsgruppe Alexandria katalogisiert die Artikel auf dem Matheplaneten]

 
Verwandte Links
 
Besucherzähler 367
 
Aufrufstatistik des Artikels
Insgesamt 8 externe Besuche zwischen 2017.11 und 2017.11 [Anzeigen]
DomainAnzahlProz
http://matheplanet.com787.5%87.5 %
http://google.de112.5%12.5 %

Aufrufer der letzten 5 Tage im Einzelnen
Insgesamt 6 Aufrufe in den letzten 5 Tagen. [Anzeigen]
DatumAufrufer-URL
2017.11.19-2017.11.24 (5x)http://matheplanet.com/
2017.11.21 16:45http://google.de/

[Seitenanfang]

" Zeichnen einer Weltkugel mit einem Commodore Plus 4" | 4 Kommentare
 
Für den Inhalt der Kommentare sind die Verfasser verantwortlich.

Re: Zeichnen einer Weltkugel mit einem Commodore Plus 4
von buh am Do. 19. Oktober 2017 17:39:56


Was für eine Erinnerung!

Den Globus habe ich auf einem KC 85/3 zum Laufen gebracht; ich hätte mir aber nie die Mühe gemacht, den ganzen Code auch noch in meinen Plus 4 zu hämmern. (Damals musste man ja alles von Hand..., wenn es nicht im Radio kam und man die Daten mitschneiden konnte.)

Und wenn ich in meinem Bücherschrank grabe, finde ich vielleicht auch noch das gute alte "1x1 des Programmierens",

denkt mit Tränen in den Augen

buh2k+17

P.S. Der 85/3 war nur geliehen und der Plus 4 hatte vermutlich eine Sollbruchstelle; aber er hat bis ca. 1997 durchgehalten.buh
P.P.S. Und weil wir gerade so schön an die gute alte Zeit denken...

 [Bearbeiten]

Re: Zeichnen einer Weltkugel mit einem Commodore Plus 4
von PhysikRabe am Do. 19. Oktober 2017 20:18:51


Ich hab noch einen echten, funktionstüchtigen Plus 4 daheim. smile Schöner Code, wenn ich mal Zeit habe versuche ich ihn zum Laufen zu bringen. Danke!

 [Bearbeiten]

Re: Zeichnen einer Weltkugel mit einem Commodore Plus 4
von Delastelle am Do. 19. Oktober 2017 21:47:59


Wir hatten 1985 einen Sharp PC 1401 - einen BASIC fähigen Taschenrechner mit 4 Kilobyte RAM und 16 Zeichen Display.
Später einen Commodore Plus 4 (64 Kilobyte RAM). Beide Computer als Geschenke aus dem Westen.
1990 haben dann meine Eltern einen 286er PC mit 1 Megabyte RAM gekauft.

Das "Globus"-Programm hatte ich früher schon mal auf einem Plus 4 abgetippt aber nicht zum Laufen bekommen.
Heute mit dem VICE-Emulator ist ein Debuggen einfacher - man kann die Geschwindigkeit um den Faktor 30 bis 50 gegenüber den alten Computern erhöhen.

 [Bearbeiten]

Re: Zeichnen einer Weltkugel mit einem Commodore Plus 4
von pzktupel am Fr. 20. Oktober 2017 07:53:12


Ich selbst hatte einen KC 85/3. Beide Computer konnten in etwa dasselbe
machen. Es war bescheiden , aber man war stolz mit wenig. Wenn man die ganze PC-Entwicklung selbst miterleben konnte , flüchtet man gerne in diese Zeit gedanklich zurück. Sowas kann man heute nicht mehr erleben und nachempfinden. Was für eine schöne Erinnerung und Zeit es doch war ! Sprichwörtlich war die Welt gefühlsmäßig damals für einen noch in Ordnung und geordneter.
Den Globus kenn ich nicht, aber es hat eine typische gewisse Austrahlung von damals ,die man nicht beschreiben kann.

Danke für die Globusdarstellung !

LG pzktupel

 [Bearbeiten]

 
All logos and trademarks in this site are property of their respective owner. The comments are property of their posters, all the rest © 2001-2017 by Matroids Matheplanet
This web site was made with PHP-Nuke, a web portal system written in PHP. PHP-Nuke is Free Software released under the GNU/GPL license.
Ich distanziere mich von rechtswidrigen oder anstößigen Inhalten, die sich trotz aufmerksamer Prüfung hinter hier verwendeten Links verbergen mögen.
Lesen Sie die Nutzungsbedingungen, die Distanzierung, die Datenschutzerklärung und das Impressum.
[Seitenanfang]