Auswahl  Home / Seite ohne Frame
Aktuell und Interessant ai
Artikelübersicht/-suche
Alle Links / Mathe-Links
Fach- & Sachbücher Reviews
Mitglieder / Karte
Registrieren/Login
Arbeitsgruppen
? im neuen Schwätz Werde Mathe-Millionär!
Formeleditor fedgeo
Schwarzes Brett Aktion im Forum Zur Anmeldung Beiträge in den Foren  Frage stellen Zum Mathe-Forum Zum Schulmathe-Forum Zum Physik-Forum Zum Informatik-Forum Suche im Forum Fragen? Bedienungsanleitung Suche Kontakt Mail an Matroid [Keine Übungsaufgaben!] Impressum Bitte beachten Sie unsere Nutzungsbedingungen, die Distanzierung, unsere Datenschutzerklärung und die Forumregeln. Sie können Mitglied werden. Mitglieder können Fragen stellen und im Forum aktiv sein. Für Mitglieder  Mathematisch für Anfänger
Wer ist Online Sie können Mitglied werden: Klick hier. |
|
Wie unterstütze ich den Matheplaneten mit Geld?
Printer-friendly version
Gnuplot erlaubt eine Menge von Ausgabeformaten und Kanälen. Üblicherweise will man das Resultat zuerst sehen und nach den allfälligen Korrekturen auch als Bild speichern.
Die Ausgabekanäle werden mit dem Befehl "set terminal ..." gesetzt. Will man das Resultat nur anschauen genügt das automatisch eingestellte, zum Betriebssystem passende terminal. Dazu gehören zum Beispiel das x11-Terminal unter Linux und Unix und das aqua-Terminal unter Mac-OSX. Diese Terminals erzeugen ein Anzeigefenster. Mit dem x-11 Terminal kann man 3-d Grafiken mit der Maus drehen. Je nach Typ kann man das Resultat auch abspeichern.
Zum Erzeugen von hochwertigen Graphiken sind aber die postscript und svg terminals viel besser geeignet. Die reinen Anzeigeterminals versagen oft schon bei der Anzeige von verschiedenen Linienstilen, welche nur über die Vektorgraphik-Formate ausgegeben werden. Wenn eine, als "gestrichelt" definierte Linie, also einfach durchgezogen wird, so ist daran oft das Ausgabeformat schuld.
Vor dem plot-Befehl muss also das Ausgabeformat und allenfalls die Ausgabedatei definiert werden. Will man das Resultat mehreren Terminals zuführen, so kann man nach dem ersten plot-Befehl einfach das Terminal neu setzten und den replot Befehl anhängen, wie unten gezeigt:
\sourceon gnuplot
#Resultat auf dem Bildschirm betrachten
set terminal x11
plot ....
...
#Die selbe Graphik im postscript-Format speichern
set terminal postscript
set output "meinPlot.ps"
replot
----------------
#...oder im svg-Format
set terminal svg
set output "mein_plot.svg"
----------------
#Falls die Ansprüche an die Qualität (Pixelgrafik genügt) nicht so hoch sind:
set terminal png
set output "mein_plot.png"
\sourceoff
\sourceon gnuplot
Z(freq) = abs(1/({0,1}*C*2*3.14*freq*1000))
C = 1*10**(-9)
set dummy freq
set mxtics 10
set grid xtics mxtics lt 0 ls 0
set grid ytics mytics lt 0 ls 0
set key default
set title "Impedanz eines idealen 1nF Kondensators"
set xlabel "Frequenz in kHz"
set xrange [1.0 : 10000.0]
set yrange [10:100000.0]
set ylabel "Impedanz in Ohm"
set logscale xy
set tics out
plot Z(freq)
\sourceoff
Zu beachten ist, dass in gnuplot der Potenzoperator ** und nicht ^ lautet.
Nun kann es aber durchaus vorkommen, dass Schaltungen mit idealen Bauteilen in der Realität nicht funktionieren. Der Grund ist, dass der Kondensator Anschlussleitungen besitzt. Diese haben im Beispiel eine Induktivität von 1nH in Serie zum Kondensator.
\sourceon gnuplot
Z(freq) = abs(1/({0,1}*C*2*pi*freq*10**6)+({0,1}*L*2*pi*freq*10**6))
C = 1*10**(-9)
L = 1*10**(-9)
set dummy freq
set mxtics 10
set grid xtics mxtics lt 0 ls 0
set grid ytics mytics lt 0 ls 0
set key default
set title "Impedanz eines realen 1nF Kondensators"
set xlabel "Frequenz in MHz"
set xrange [10.0 : 1000.0]
set yrange [0.1:100.0]
set ylabel "Impedanz in Ohm"
set logscale xy
set tics out
plot Z(freq)
\sourceoff
Im folgenden Diagramm ist die Phase der Spannung in Bezug zum Strom aufgezeichnet. Oberhalb der Frequenz 1/(2*\pi*\sqrt(C*L)) dominiert das Verhalten der Spule. Das heisst ab etwa 160MHz eilt die Spannung dem Strom voraus.
Was wie ein Sprung aussieht in diesem Diagrammen, ist im komplexen nur ein Nulldurchgang. Die Amplitude wird immer kleiner und der "Sprung" findet dort statt, wo kein Signal mehr vorhanden ist.
\sourceon gnuplot
Phase(freq) = 180/pi*arg(1/({0,1}*C*2*pi*freq*10**6)+({0,1}*L*2*pi*freq*10**6))
C = 1*10**(-9)
L = 1*10**(-9)
set dummy freq
set mxtics 10
set grid xtics mxtics lt 0 ls 0
set grid ytics mytics lt 0 ls 0
set key default
set title "Phasenverlauf eines realen 1nF Kondensators" font "Helvetica,30"
set xlabel "Frequenz in MHz" font "Helvetica,20"
set xrange [10.0 : 1000.0]
set yrange [-180:180]
set xtics font "Helvetica,20"
set nokey
set ytics ("-180°" -180,"-135°" -135,"-90°" -90,"-45°" -45,"0°" 0,"45°" 45,"90°" 90,"135°" 135,"180°" 180) font "Helvetica,20"
set ylabel "Phase" font "Helvetica,20"
set logscale x
set tics out
plot Phase(freq)
\sourceoff
Wenn man nun bedenkt, dass ein reales Bauteil auch noch Anschlusswiderstände besitzt, dann sehen die Kurven schon wesentlich "runder" aus. Die Abbildungen zeigen zeigen den Kondensator mit 0.5 Ohm Anschlusswiderstand in Serie:
\sourceon gnuplot
reset
Imp(freq) = abs(1/({0,1}*C*2*pi*freq*10**6)+({0,1}*L*2*pi*freq*10**6)+0.5)
C = 1*10**(-9)
L = 1*10**(-9)
set dummy freq
set mxtics 10
set grid xtics mxtics lt 0 ls 0
set grid ytics mytics lt 0 ls 0
set key default
set title "Impedanz eines realen 1nF Kondensators" font "Helvetica,30"
set xlabel "Frequenz in MHz" font "Helvetica,20"
set xrange [10.0 : 1000.0]
set yrange [0.1:100.0]
set nokey
set xtics font "Helvetica,20"
set ytics font "Helvetica,20"
set ylabel "Impedanz in Ohm" font "Helvetica,20"
set logscale xy
set tics out
plot Imp(freq)
\sourceoff
Zum Schluss noch das Gegenstück zum Kondensator; die Spule:
\sourceon gnuplot
reset
Imp(freq) = abs(1/(({0,1}*C*2*pi*freq*10**3)+1/({0,1}*L*2*pi*freq*10**3+200)))
C = 1*10**(-10)
L = 1*10**(-3)
set dummy freq
set mxtics 10
set grid xtics mxtics lt 0 ls 0
set grid ytics mytics lt 0 ls 0
set key default
set title "Impedanz einer realen 1mH Spule" font "Helvetica,30"
set xlabel "Frequenz in kHz" font "Helvetica,20"
set xrange [10 : 1000.0]
set yrange [100:10000.0]
set nokey
set xtics font "Helvetica,20"
set ytics font "Helvetica,20"
set ylabel "Impedanz in Ohm" font "Helvetica,20"
set logscale xy
set tics out
set samples 400
plot Imp(freq)
\sourceoff
\sourceon gnuplot
reset
set term aqua
F(jw)=20*log10(abs(K/(1+jw*{0,1}*T)))
K = 2
T = 0.001
set dummy jw
# Typen von Hilfslinien
set style line 3 lt 3 lw 1
set style arrow 3 nohead lt 3 lw 1
set style line 4 lt 3 lw 1
set style arrow 4 nohead lt 3 lw 1
# Hilfslinien zeichnen
set arrow 1 from 100,6 to 1000,6 as 3
set arrow 2 from 1000,6 to 100000,-34 as 3
set arrow 3 from 2000,0 to 20000,0 as 4
set arrow 4 from 20000,0 to 20000,-20 as 4
# Achsen und Einteilungen
set mxtics 10
set grid xtics mxtics
set grid ytics mytics
set xrange [100 : 100000.0]
set yrange [-40:10.0]
set logscale x
set ytics (10,6,3,0,-10,-20,-30,-40)
set tics out
# Beschriftungen
set nokey
set label 3 "Eckfrequenz" at 1000,7 l font "Helvetica,15"
set label 4 "Steigung -20dB/Dekade" at 3500,-2 l font "Helvetica,15"
set title "Bode Diagramm des PT1 Elements" font "Helvetica,30"
set ylabel "|F(jw)| in dB" font "Helvetica,20"
set xlabel "Kreisfrequenz w" font "Helvetica,20"
plot F(jw)
\sourceoff
Schön wären gestrichelte Linien. Diese gibt es jedoch nicht auf jedem Terminal zu haben. Ich werde später noch ein Beispiel mit Postscript zeigen.
Bei diesem Beispiel habe ich Phasen- und Amplitudengang in einem Diagramm zusammengefasst. Dazu muss gnuplot in den Multiplot-Modus gesetzt werden. Dieser muss wieder zurückgesetzt werden, um in den gnuplot-Standardmodus zurück zu gelangen. Befehle, wie das Setzen des terminals funktionieren nur im Standardmodus.
Der gnuplot Code dazu sieht folgendermassen aus:
\sourceon gnuplot
reset
unset multiplot
set samples 2001
set terminal aqua
G(w)=K*w0**2/((w*{0,1})**2+2*D*w0*{0,1}*w+w0**2)
dB(x)=20*log10(abs(G(x)))
P(x) = arg(G(x))*180/pi
K = 1
D = 0.2
w0 = 1000
# Typen von Hilfslinien
set style line 3 lt 3 lw 1
set style arrow 3 lt 3 lw 1
set style line 4 lt 3 lw 1
set style arrow 4 nohead lt 3 lw 1
set multiplot
# Amplitude
set size 1,0.5
set origin 0,0.5
# Achsen und Einteilungen
set mxtics 10
set grid xtics mxtics
set grid ytics mytics
set xrange [100 : 10000.0]
set yrange [-40:10.0]
set logscale x
set ytics (10,0,-10,-20,-30,-40)
set tics out
# Beschriftungen
set nokey
set label 2 "Resonanz bei 959Hz" at 450,-5 l font "Helvetica,15"
set label 3 "Überhöhung 8.1dB" at 1300,6 l font "Helvetica,15"
set label 4 "Steigung -40dB/Dekade" at 1000,-20 l font "Helvetica,15"
set xlabel "jw"
set ylabel "|G(jw)| in dB" font "Helvetica,15"
set xlabel "Kreisfrequenz w" font "Helvetica,15"
set title "PT2 Element: Amplitudengang" font "Helvetica,20"
#Asymtoten
set arrow 1 from 100,0 to 1000,0 as 4
set arrow 2 from 1000,0 to 10000,-40 as 4
set arrow 3 from 959,0 to 959,8.1 as 3
set arrow 4 from 959,8.1 to 1250,8.1 as 4
#Amplitudengang
plot dB(x)
reset
# Phase
set size 1,0.5
set origin 0,0
# Achsen und Einteilungen
set mxtics 10
set grid xtics mxtics
set grid ytics mytics
set xrange [100 : 10000.0]
set yrange [-180 : 0.0]
set logscale x
# Beschriftungen
set nokey
set xlabel "jw"
set ylabel "Phase in Grad" font "Helvetica,15"
set xlabel "Kreisfrequenz w" font "Helvetica,15"
set title "PT2 Element Phasengang" font "Helvetica,20"
plot P(x)
unset multiplot
\sourceoff
Die Funktion wurde mit gnuplot folgendermassen erzeugt:
\sourceon gnuplot
G(w)=K*w*{0,1}/(1+T1*w*{0,1})
dB(x)=20*log10(abs(G(x)))
P(x) = arg(G(x))*180/pi
K = 0.01
T1 = 0.001
\sourceoff
\sourceon gnuplot
G(w)=K*(1+TN*w*{0,1})*(1+TV*w*{0,1})/(TN*w*{0,1})
dB(x)=20*log10(abs(G(x)))
P(x) = arg(G(x))*180/pi
K = 1
TN = 0.01
TV = 0.001
\sourceoff
Dieses Diagramm kann man nicht mehr direkt aus der Übertragungsfunktion ableiten. Die additive Form ist für die Konstruktion von Reglern zwar vorteilhaft, der Frequenzgang kann aber erst nach einigen Umrechnungen abgeschätzt werden.
Um die additive in die multiplikative Form umzuwandeln, muss man Darstellungen mit gleichen Null- und Polstellen und gleichem konstanten Faktor finden.
Für die Multiplikative Form wurde der Index m und für die additive Form der Index a verwendet. Unten steht das Resultat der Umrechnung:
T_(Na)>T_(Va)>T_1
K_(Rm)=K_(Ra)/2*(1+T_1/T_(Na)+sqrt((1-T_1/T_(Na))^2-4*T_(Va)/T_(Na))), K_(Ra)=K_(Rm)*(T_(Nm)+T_(Vm)-T_1)/T_(Nm)
T_(Nm)=T_(Na)/2*(1+T_1/T_(Na)+sqrt((1-T_1/T_(Na))^2-4*T_(Va)/T_(Na))), T_(Na)=T_(Nm)+T_(Vm)-T_1
T_(Vm)=K_(Ra)/2*(1+T_1/T_(Na)+sqrt((1-T_1/T_(Na))^2-4*T_(Va)/T_(Na))), T_(Va)=(T_(Nm)*(T_(Vm))/(T_(Nm)+T_(Vm)-T_1)
Mit einem multiplikativen Regler lässt sich nur dann ein additiver Regler nachbilden, wenn gilt:
T_(Na)>=2*T_(Va)+T_1+2*sqrt(T_(Va)^2+T_(Va)*T1)
Anders herum kann ein additiver Regler nur dann einen multiplikativen Regler nachbilden, falls:
T_(Na)>=4*T_(Va)
Bei diesem Diagramm habe ich die postscript Ausgabe verwendet. Damit sind sowohl gestrichelte Linien, als auch griechische Buchstaben darstellbar. In den Codeabschnitten unten ist die Verwendung der Funktion und der griechischen Buchstaben gezeigt. Auf anderen Terminals werden die Symbol-Sequenzen einfach wie im Quelltext angezeigt.
\sourceon gnuplot
set terminal postscript enhanced landscape color lw 2 "Times-Roman" 20
set output "PID_A.ps"
G(w)=K*(1+1/(TN*w*{0,1})+TV*w*{0,1}/(1+T1*w*{0,1}))
dB(x)=20*log10(abs(G(x)))
P(x) = arg(G(x))*180/pi
K = 2
TN = 0.01
TV = 0.002
T1 = 0.001
set label 1 "{/Symbol w}_2" at 145,-4 l
\sourceoff
Get link to this article
Comments
Für diesen Artikel gibt es keine pdf-Datei
Dieser Artikel ist im Verzeichnis der 
This web site was originally made with PHP-Nuke, a former web portal system written in PHP that seems no longer to be maintained nor supported. PHP-Nuke is Free Software released under the GNU/GPL license.
Ich distanziere mich von rechtswidrigen oder anstößigen Inhalten, die sich trotz aufmerksamer Prüfung hinter hier verwendeten Links verbergen mögen.
Lesen Sie die Nutzungsbedingungen, die Distanzierung, die Datenschutzerklärung und das Impressum.
[Seitenanfang]